Delphi XE7のAndroidアプリケーションで通信状態が、モバイル通信かWi-Fi通信か未接続かを判定する方法を紹介します。

モバイル通信の時は送受信するデータのサイズを小さくしてアプリケーションのレスポンスを良くするなどの工夫ができます。

メニューの「プロジェクト」→「オプション」→「使用する権限」から「ネットワーク状態へのアクセス」にチェックを入れます。

Androidのandroid.net.ConnectivityManagerクラスとandroid.net.NetworkInfoクラスを使用するため、ブリッジファイルを作成します。

Java2OP.exe -classes android.net.ConnectivityManager android.net.NetworkInfo -unit Androidapi.JNI.Interfaces

ボタンを押したときに、通信状態を表示するプログラムです。

uses
  Androidapi.JNIBridge,
  Androidapi.Helpers,
  Androidapi.JNI.JavaTypes,
  Androidapi.JNI.GraphicsContentViewText,
  Androidapi.JNI.Interfaces;

procedure TForm1.Button1Click(Sender: TObject);
var
  ConnectivityManagerObj: JObject;
  ConnectivityManager: JConnectivityManager;
  NetworkInfo: JNetworkInfo;
  NetworkType: Integer;
begin
  ConnectivityManagerObj := SharedActivityContext.getSystemService
    (TJContext.JavaClass.CONNECTIVITY_SERVICE);
  ConnectivityManager := TJConnectivityManager.Wrap
    ((ConnectivityManagerObj as ILocalObject).GetObjectID);

  NetworkInfo := ConnectivityManager.getActiveNetworkInfo();
  if NetworkInfo = nil then
  begin
    ShowMessage('未接続');
    Exit;
  end;

  NetworkType := NetworkInfo.getType;
  if NetworkType = TJConnectivityManager.JavaClass.TYPE_WIFI then
  begin
    ShowMessage('Wi-Fiデータ通信');
  end
  else if NetworkType = TJConnectivityManager.JavaClass.TYPE_MOBILE then
  begin
    ShowMessage('モバイルデータ通信');
  end;
end;

ボタンを押すと、通信状態が表示されます。

開発環境はDelphi XE7 Update1、プラットフォームはAndroidで発生する問題です。
メインスレッド以外でTBitmapを作成すると例外が発生します。

procedure TForm1.Button1Click(Sender: TObject);
begin
  TThread.CreateAnonymousThread(
    procedure
    var
      Bmp: TBitmap;
    begin
      Bmp := TBitmap.Create(100, 100);
    end).Start;
end;

$A2355201 で初回の例外が発生しました。例外クラスは EBitmapSizeTooBig メッセージは ‘ビットマップ サイズが大きすぎます。’。 プロセス Project1.apk (22537)

この問題はRAD Studio Quality Portalにも登録されています。

• [RSP-9589] TBitmap creation failed on Andriod when calling from thread – Embarcadero Technologies

例外が発生する箇所はTBitmap.SetSizeメソッドの中なので、SetSizeメソッドを実行しても同じように例外が発生します。

procedure TForm1.Button1Click(Sender: TObject);
begin
  TThread.CreateAnonymousThread(
    procedure
    var
      Bmp: TBitmap;
    begin
      Bmp := TBitmap.Create;
      Bmp.SetSize(100, 100); //ここで例外発生
    end).Start;
end;

AndroidでWebブラウザのリンクをクリックするとDelphiアプリケーションを起動する方法を紹介します。

Delphiアプリケーションの作成

アプリケーションが起動したときに、リンクのURLを取得してブラウザコンポーネントに表示します。

procedure TForm1.FormCreate(Sender: TObject);
var
  Intent: JIntent;
  Uri: JString;
begin
  Intent := SharedActivity.getIntent;
  if TJIntent.JavaClass.ACTION_VIEW.equals(Intent.getAction) then
  begin
    Uri := Intent.getDataString;
    FWebBrowser.URL := JStringToString(Uri);
  end;
end;

AndroidManifest.template.xmlの編集

AndroidManifest.xmlにインテントフィルタを設定します。

プロジェクトファイルのあるフォルダーに「AndroidManifest.template.xml」というファイルがあります。
この「AndroidManifest.template.xml」をテキストエディタで開きます。

次のコードを追加します。

        <intent-filter>
            <action android:name="android.intent.action.VIEW" />
            <category android:name="android.intent.category.DEFAULT" />
            <category android:name="android.intent.category.BROWSABLE" />
            <data android:scheme="http" android:host="www.gesource.jp" android:path="/" />
        </intent-filter>

dataタグで、アプリケーションを起動するリンクを設定しています。
「https://www.gesource.jp/」のリンクをクリックしたとき、Delphiアプリケーションでリンクを開くことができます。

リンクは「http」に限られているわけではありません。
dataタグを次のようにすると、「test://hello」のリンクをクリックしたときに、アプリケーションを起動します。

<data android:scheme="test" android:host="hello" />